cmake_minimum_required(VERSION 3.5)

cmake_policy(SET CMP0002 OLD)

find_program(GIT_PROGRAM git)
find_program(CCACHE_PROGRAM ccache)

option(CP_BUILD_TESTS "Build cdnskey-processor tests" ON)

set(SERVER_VERSION "1.2.0")
if(NOT SERVER_VERSION)
    if(NOT GIT_PROGRAM)
        message(FATAL_ERROR "git not found; you need to pass -DSERVER_VERSION=")
    endif()
    execute_process(COMMAND ${GIT_PROGRAM} "describe" "--tags"
                    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
                    OUTPUT_VARIABLE SERVER_VERSION)
endif()
message(STATUS "SERVER_VERSION: ${SERVER_VERSION}")

string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" SERVER_VERSION_MAJOR_MINOR_PATCH ${SERVER_VERSION})
project(CdnskeyProcessor
    VERSION ${SERVER_VERSION_MAJOR_MINOR_PATCH}
    LANGUAGES CXX)
message(STATUS "PROJECT_VERSION: ${PROJECT_VERSION}")

if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

set(TARBALL_FILE_NAME "${PROJECT_NAME}-${SERVER_VERSION}")
set(LIBCP_PREFIX ${TARBALL_FILE_NAME}/external/lib/libcdnskey-processor)

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set_default(THREADS_PREFER_PTHREAD_FLAG ON)
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "Enable/disable log calls at compile time according to global level.")
option(FMT_STRING_ALIAS "Enable compile-time format string checks." ON)
option(FMT_HEADER_ONLY "Use fmt library in header-only manner." OFF) # significantly reduce build time
set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)
set(AMQP-CPP_LINUX_TCP ON CACHE BOOL "CPP_LINUX_TCP")
set(PROGRAM_OPTIONS_LINE_LENGTH "128" CACHE STRING "Maximum line length of text printed on console")

find_package(Threads REQUIRED)

find_package(Boost 1.66.0
    COMPONENTS
        program_options
    REQUIRED)

find_package(PkgConfig)
pkg_check_modules(EVENT_CORE REQUIRED libevent_core)

find_package(OpenSSL REQUIRED)

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR}
                ${EVENT_CORE_INCLUDE_DIRS})
        target_compile_options(${target_name}
            PUBLIC
                ${EVENT_CORE_CFLAGS_OTHER}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
    endforeach()
endfunction()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE "-Wno-unused-parameter")
    endforeach()
endfunction()

set_default(LIBLOG_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/liblog)
if(NOT IS_ABSOLUTE ${LIBLOG_DIR})
    set(LIBLOG_DIR ${CMAKE_BINARY_DIR}/${LIBLOG_DIR})
endif()
if(NOT EXISTS ${LIBLOG_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBLOG_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBLOG_DIR")
endif()
if(NOT TARGET LibLog::library)
    add_subdirectory(${LIBLOG_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/liblog EXCLUDE_FROM_ALL)
endif()

set_default(LIBPG_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/libpg)
if(NOT IS_ABSOLUTE ${LIBPG_DIR})
    set(LIBPG_DIR ${CMAKE_BINARY_DIR}/${LIBPG_DIR})
endif()
if(NOT EXISTS ${LIBPG_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBPG_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBPG_DIR")
endif()
if(NOT TARGET LibPg::library)
    add_subdirectory(${LIBPG_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/libpg EXCLUDE_FROM_ALL)
endif()

set_default(LIBAMQPCPP_DIR ${CMAKE_CURRENT_SOURCE_DIR}/3rd_party/AMQP-CPP)
if(NOT IS_ABSOLUTE ${LIBAMQPCPP_DIR})
    set(LIBAMQPCPP_DIR ${CMAKE_BINARY_DIR}/${LIBAMQPCPP_DIR})
endif()
if(NOT EXISTS ${LIBAMQPCPP_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBAMQPCPP_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBAMQPCPP_DIR")
endif()
if(NOT TARGET libamqpcpp)
    add_subdirectory(${LIBAMQPCPP_DIR} ${CMAKE_CURRENT_BINARY_DIR}/3rd_party/AMQP-CPP EXCLUDE_FROM_ALL)
endif()

set_default(API_CDNSKEY_PROCESSOR_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/api/cdnskey-processor)
if(NOT IS_ABSOLUTE ${API_CDNSKEY_PROCESSOR_DIR})
    set(API_CDNSKEY_PROCESSOR_DIR ${CMAKE_BINARY_DIR}/${API_CDNSKEY_PROCESSOR_DIR})
endif()
if(NOT EXISTS ${API_CDNSKEY_PROCESSOR_DIR}/cmake/c++.cmake)
    message(FATAL_ERROR "${API_CDNSKEY_PROCESSOR_DIR}/cmake/c++.cmake does not exist; you need to pass -DAPI_CDNSKEY_PROCESSOR_DIR")
endif()

include(${API_CDNSKEY_PROCESSOR_DIR}/cmake/c++.cmake)
include(${CMAKE_CURRENT_SOURCE_DIR}/protos/CMakeLists.txt)

set_default(HAVE_BOOST_SERIALIZATION 1)

set_default(VERSION ${PROJECT_VERSION})
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)

add_library(cdnskey-processor-iface STATIC
    ${CDNSKEY_PROCESSOR_PROTO_SRCS}
    ${INTERNAL_CDNSKEY_PROCESSOR_PROTO_SRCS}
    ${CDNSKEY_PROCESSOR_GRPC_SRCS})

add_library(CdnskeyProcessorIface::library ALIAS cdnskey-processor-iface)

target_link_libraries(cdnskey-processor-iface
    -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state
    protobuf::libprotobuf)

set_grpc_properties_on_targets(
    cdnskey-processor-iface)


add_library(cdnskey-processor-conf STATIC
    src/cfg/database.cc
    src/cfg/log.cc
    src/cfg/validator.cc)
target_link_libraries(cdnskey-processor-conf
    PUBLIC
        Boost::program_options
    PRIVATE
        LibLog::library)
add_library(CdnskeyProcessorConf::library ALIAS cdnskey-processor-conf)

add_library(cdnskey-processor-storage STATIC
    src/database.cc
    src/storage.cc)
target_link_libraries(cdnskey-processor-storage
    PUBLIC
        LibPg::library
    PRIVATE
        LibLog::library)
add_library(CdnskeyProcessorStorage::library ALIAS cdnskey-processor-storage)

add_library(cdnskey-processor-internal STATIC
    src/internal/amqp/bind_queue.cc
    src/internal/amqp/consume.cc
    src/internal/amqp/exchange.cc
    src/internal/amqp/libevent_handler.cc
    src/internal/amqp/publish.cc
    src/internal/amqp/queue.cc
    src/internal/amqp/reliable_tcp_channel.cc
    src/internal/amqp/tcp_connection.cc
    src/internal/libevent_timer.cc
    src/internal/scan_result.cc
    src/internal/subprocess.cc
    src/scan_task.cc
    src/unwrapper/unwrapper.cc
    src/wrapper/wrapper.cc)
target_link_libraries(cdnskey-processor-internal
    PUBLIC
        amqpcpp
        CdnskeyProcessorIface::library
        ${EVENT_CORE_LINK_LIBRARIES}
        LibStrong::library
    PRIVATE
        LibLog::library)
add_library(CdnskeyProcessorInternal::library ALIAS cdnskey-processor-internal)

add_executable(cdnskey-processor-api
    src/api.cc
    src/cfg/api.cc
    src/grpc_service_report.cc
    src/grpc_service_supervisor.cc)

add_executable(cdnskey-processor-master
    src/master.cc
    src/cfg/master.cc)

add_executable(cdnskey-processor-worker
    src/worker.cc
    src/cfg/worker.cc)

target_link_libraries(cdnskey-processor-master PRIVATE
    CdnskeyProcessorConf::library
    CdnskeyProcessorInternal::library
    CdnskeyProcessorStorage::library
    LibLog::library)

target_link_libraries(cdnskey-processor-worker PRIVATE
    CdnskeyProcessorConf::library
    CdnskeyProcessorInternal::library
    LibLog::library)

target_link_libraries(cdnskey-processor-api PRIVATE
    CdnskeyProcessorConf::library
    CdnskeyProcessorInternal::library
    CdnskeyProcessorStorage::library
    LibLog::library)

set_common_properties_on_targets(
    cdnskey-processor-conf
    cdnskey-processor-storage
    cdnskey-processor-iface
    cdnskey-processor-internal
    cdnskey-processor-api
    cdnskey-processor-master
    cdnskey-processor-worker)

if(CP_BUILD_TESTS)
    set_default(PACKAGE "cdnskey-processor-api;cdnskey-processor-master;cdnskey-processor-worker;cdnskey-processor-db-loader")
    add_subdirectory(test)
else()
    set_default(PACKAGE "cdnskey-processor-api;cdnskey-processor-master;cdnskey-processor-worker")
endif()

include(GNUInstallDirs)

install(TARGETS ${PACKAGE}
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

add_custom_target(uninstall
    COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
    COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

if(EXISTS ${CMAKE_SOURCE_DIR}/.git AND GIT_PROGRAM)
    if(NOT TARGET dist)
        add_custom_target(dist_libamqpcpp
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/libamqpcpp/ HEAD > ${CMAKE_BINARY_DIR}/.libamqpcpp.tar
            WORKING_DIRECTORY ${LIBPG_DIR})
        add_custom_target(dist_libpg
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/libpg/ HEAD > ${CMAKE_BINARY_DIR}/.libpg.tar
            WORKING_DIRECTORY ${LIBPG_DIR})
        add_custom_target(dist_liblog
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog.tar
            WORKING_DIRECTORY ${LIBLOG_DIR})
        add_custom_target(dist_liblog_spdlog
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblog/3rd_party/lib/spdlog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
            WORKING_DIRECTORY ${LIBLOG_DIR}/3rd_party/lib/spdlog/)
        add_custom_target(dist
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
            COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.libamqpcpp.tar
            COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.libpg.tar
            COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog.tar
            COMMAND tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
            COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz
            COMMAND rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.libamqpcpp.tar ${CMAKE_BINARY_DIR}/.libpg.tar ${CMAKE_BINARY_DIR}/.liblog.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
            DEPENDS dist_libamqpcpp dist_libpg dist_liblog dist_liblog_spdlog
            WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
    endif()

    if(DEFINED ENV{DISTCHECK_CMAKE_FLAGS})
        set(distcheck_flags $ENV{DISTCHECK_CMAKE_FLAGS})
    endif()

    if(NOT TARGET distcheck)
        set(DISTCHECK_BUILD_DIR "_build")
        set(DISTCHECK_INSTALL_DIR "_inst")
        if(${CMAKE_GENERATOR} STREQUAL "Ninja")
            set(DISTCHECK_BUILD_CMD "ninja")
        else()
            set(DISTCHECK_BUILD_CMD "$(MAKE)")
        endif()
        add_custom_target(clean_before_distcheck
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            COMMENT "cleaning before distcheck start")
        add_custom_target(distcheck_make_dirs
            COMMAND mkdir ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR}
            COMMENT "make distcheck build and install directories"
            DEPENDS clean_before_distcheck)
        add_custom_target(distcheck_unpack_archive
            COMMAND tar xzf ${TARBALL_FILE_NAME}.tar.gz
            COMMENT "Checking the distribution archive..."
            DEPENDS dist distcheck_make_dirs)
        add_custom_target(distcheck_configure
            COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR} ${distcheck_flags} -DSERVER_VERSION=${SERVER_VERSION} -DCMAKE_INSTALL_PREFIX=../${DISTCHECK_INSTALL_DIR} ../${TARBALL_FILE_NAME}
            COMMENT "configure distcheck"
            DEPENDS distcheck_unpack_archive
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_make
            COMMAND ${DISTCHECK_BUILD_CMD}
            COMMENT "make"
            DEPENDS distcheck_configure
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_install
            COMMAND ${DISTCHECK_BUILD_CMD} install
            COMMENT "make install"
            DEPENDS distcheck_make
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_uninstall
            COMMAND ${DISTCHECK_BUILD_CMD} uninstall
            COMMENT "make uninstall"
            DEPENDS distcheck_install
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_clean
            COMMAND ${DISTCHECK_BUILD_CMD} clean
            COMMENT "make clean"
            DEPENDS distcheck_uninstall
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            COMMENT "PASS: '${TARBALL_FILE_NAME}.tar.gz' is ready for distribution."
            DEPENDS distcheck_clean)
    endif()
else()
    message(STATUS "no git -- not including dist and distcheck targets")
endif()
