cmake_minimum_required(VERSION 3.5)
set(CMAKE_POLICY_DEFAULT_CMP0077 "NEW")

# build options

option(LIBTYPIST_BUILD_TESTS "Build ${PACKAGE_NAME} tests" ON)
option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)
option(LIBTYPIST_USE_SSL "If enabled, HTTPS/SSL will be supported" ON)

# compile options

set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type. Possible values are empty, Debug, Release, RelWithDebInfo, MinSizeRel, ...")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "This will turn on/off logging statements at compile time.")
set(FMT_STRING_ALIAS "1" CACHE STRING "Constructs a compile-time format string.")
set(FMT_HEADER_ONLY "0" CACHE STRING "Use fmt library in the header-only manner.")

# project details

include("cmake/package.cmake")

package(libtypist
    FULL_VERSION "2.0.0")

project(LibTypist
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# package dependencies

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")

# dependencies

set(CMAKE_FIND_PACKAGE_PREFER_CONFIG TRUE)

find_package(Boost 1.53.0
    COMPONENTS
        system
        thread
        serialization
        filesystem
    REQUIRED)

if (LIBTYPIST_USE_SSL)
    find_package(OpenSSL REQUIRED)
endif()

find_package(nlohmann_json 3.2.0 REQUIRED)

# configuration files

configure_file(${CMAKE_CURRENT_SOURCE_DIR}/conf.hh.cmake ${CMAKE_CURRENT_BINARY_DIR}/src/conf.hh)

# build

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
        target_include_directories(${target_name}
            PUBLIC
                $<INSTALL_INTERFACE:include>
                $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
                $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
            PRIVATE
                ${CMAKE_CURRENT_SOURCE_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
    endforeach()
endfunction()

add_library(typist
    STATIC
        src/connection.cc
        src/exception.cc
        src/json.cc
        src/render.cc)

add_library(LibTypist::library ALIAS typist)

target_link_libraries(typist
    PRIVATE
        Threads::Threads
        Boost::system
        Boost::thread
        Boost::serialization
        Boost::filesystem
        nlohmann_json::nlohmann_json
    PUBLIC
        LibStrong::library)

if (LIBTYPIST_USE_SSL)
target_link_libraries(typist
    PRIVATE
        OpenSSL::SSL
        OpenSSL::Crypto)
endif()

set_common_properties_on_targets(
    typist)

if(LIBTYPIST_BUILD_TESTS)

add_subdirectory(test)

endif()

# installation

find_program(GIT_PROGRAM git)
get_directory_property(HAS_PARENT PARENT_DIRECTORY)
if(NOT HAS_PARENT)

    include(GNUInstallDirs)

    install(TARGETS typist
        DESTINATION ${CMAKE_INSTALL_SBINDIR})

    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

endif()

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_PREFIX "${LIBTYPIST_PREFIX}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")
