cmake_minimum_required(VERSION 3.5)

# project details

include("cmake/package.cmake")
package(libgrill
    FULL_VERSION "4.0.0")

project(LibGrill
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

option(LIBGRILL_BUILD_TESTS "Build ${PACKAGE_NAME} tests" OFF)

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set_default(THREADS_PREFER_PTHREAD_FLAG ON)
set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)

find_program(CCACHE_PROGRAM ccache)
if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

find_package(Boost 1.66.0
    COMPONENTS
        date_time
        system
    REQUIRED)

include("cmake/package_dependencies.cmake")
add_package_dependencies(FROM_FILE "dependencies.txt")

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib")
        target_include_directories(${target_name}
            PUBLIC
                $<INSTALL_INTERFACE:include>
                $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
                $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
            PRIVATE
                ${CMAKE_CURRENT_SOURCE_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
    endforeach()
endfunction()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE "-Wno-unused-parameter")
        target_link_libraries(${target_name}
            -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state
            protobuf::libprotobuf)
    endforeach()
endfunction()

add_library(fred-logger-iface STATIC
    ${FRED_LOGGER_PROTO_SRCS}
    ${FRED_LOGGER_GRPC_SRCS})

add_library(FredLoggerIface::library ALIAS fred-logger-iface)

set_grpc_properties_on_targets(
    fred-logger-iface)

add_library(grill STATIC
    src/connection.cc
    src/exception.cc
    src/logger/close_log_entry.cc
    src/logger/close_log_entry_exception.cc
    src/logger/close_log_entry_reply.cc
    src/logger/close_log_entry_request.cc
    src/logger/create_log_entry.cc
    src/logger/create_log_entry_request.cc
    src/logger/log_entry_id.cc
    src/logger/log_entry_property.cc
    src/logger/log_entry_request.cc
    src/logger/object_reference.cc
    src/logger/proto_unwrap.cc
    src/logger/proto_wrap.cc)

add_library(LibGrill::library ALIAS grill)

target_link_libraries(grill
    Boost::system
    Boost::date_time
    dl
    FredLoggerIface::library
    LibStrong::library
    gRPC::grpc++)

set_common_properties_on_targets(
    fred-logger-iface
    grill)

if(LIBGRILL_BUILD_TESTS)

add_subdirectory(test)

endif()

find_program(GIT_PROGRAM git)
get_directory_property(HAS_PARENT PARENT_DIRECTORY)
if(NOT HAS_PARENT)
    include(GNUInstallDirs)
    install(TARGETS grill
        DESTINATION ${CMAKE_INSTALL_SBINDIR})
    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)
endif()

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_PREFIX "${LIBGRILL_PREFIX}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")
