cmake_minimum_required(VERSION 3.5)

# build options

set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type. Possible values are empty, Debug, Release, RelWithDebInfo, MinSizeRel, ...")
option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "This will turn on/off logging statements at compile time.")
option(FMT_STRING_ALIAS "Constructs a compile-time format string." ON)
option(FMT_HEADER_ONLY "Use fmt library in header-only manner." OFF) # OFF value significantly reduce build time
option(USE_LIBLOG "Use LibLog for application logging." TRUE)
set(DEFAULT_FRED_AUCTION_WAREHOUSE_CONFIG_FILE "/etc/fred/fred-auction-warehouse.conf" CACHE STRING "Specifies the default location of fred-auction-warehouse configuration file")
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)

# project details

include("cmake/package.cmake")

package(fred-backend-registry FULL_VERSION "3.1.0")

project(FredBackendRegistry
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# package dependencies

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")
# this dependency is third party, so it will not create dist_certify target, we have to create and provide it here
provide_package_dependency_dist(certify)

# dependencies

find_program(PYTHON_PROGRAM python3)

set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
find_package(Threads REQUIRED)
find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
        random
        regex
        system
        thread
        unit_test_framework
    REQUIRED)
find_package(PkgConfig REQUIRED)

set_default(PACKAGE fred-registry-services)
set_default(HAVE_BOOST_SERIALIZATION 1)
set_default(HAVE_LOGGER 1)

find_package(OpenSSL REQUIRED)
find_package(nlohmann_json 3.2.0 REQUIRED)

# configuration files

configure_file(config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)

# build

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PUBLIC "-ggdb"
            PUBLIC "-grecord-gcc-switches"
            PUBLIC "-Wall"
            PUBLIC "-Wextra"
            PUBLIC "-fdiagnostics-color=auto")
    endforeach()
endfunction()

add_library(fred-registry-services-iface
    ${FRED_REGISTRY_PROTO_SRCS}
    ${FRED_REGISTRY_GRPC_SRCS})

add_library(FredRegistryServicesIface::library ALIAS fred-registry-services-iface)

foreach(target_name fred-registry-services-iface)
    message(STATUS "setting grpc properties on: " ${target_name})
    target_compile_options(${target_name}
        PRIVATE
            $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches -Wno-unused-parameter>)
    target_link_libraries(${target_name}
        PUBLIC
            protobuf::libprotobuf
            gRPC::grpc++)
endforeach()

add_library(http-client
    src/http/client.cc)

add_library(HttpClient::library ALIAS http-client)

target_link_libraries(http-client
PUBLIC
    Boost::system
    OpenSSL::SSL
    OpenSSL::Crypto
    certify::core
PRIVATE
    LibLog::library
    LibStrong::library)

add_library(rfc3339
    src/util/rfc3339_time.cc)

add_library(Rfc3339::library ALIAS rfc3339)

add_library(pg-util
    src/util/pg_util.cc)

add_library(PgUtil::library ALIAS pg-util)

target_link_libraries(pg-util
PUBLIC
    LibPg::library
PRIVATE
    LibLog::library)

add_library(fred-registry-core
    src/cfg.cc
    src/check_value.cc
    src/common_types.cc
    src/exceptions.cc
    src/fred_unwrap.cc
    src/fred_wrap.cc
    src/pagination_request.cc
    src/pagination_reply.cc
    src/proto_unwrap.cc
    src/proto_wrap.cc
    src/contact/contact_authinfo.cc
    src/contact/contact_common_types.cc
    src/contact/contact_data_history.cc
    src/contact/contact_handle_history.cc
    src/contact/contact_history_interval.cc
    src/contact/contact_info.cc
    src/contact/contact_info_reply.cc
    src/contact/contact_info_request.cc
    src/contact/contact_service.cc
    src/contact/contact_state.cc
    src/contact/contact_state_flags.cc
    src/contact/contact_state_history.cc
    src/contact/create_contact.cc
    src/contact/list_contacts.cc
    src/contact/list_contacts_reply.cc
    src/contact/list_contacts_request.cc
    src/contact/list_contacts_by_state.cc
    src/contact/list_contacts_by_state_reply.cc
    src/contact/list_contacts_by_state_request.cc
    src/contact/list_merge_candidates.cc
    src/contact/list_merge_candidates_reply.cc
    src/contact/list_merge_candidates_request.cc
    src/contact/merge_contacts.cc
    src/contact/merge_contacts_reply.cc
    src/contact/merge_contacts_request.cc
    src/contact/search_contact.cc
    src/contact/suggest_contacts.cc
    src/contact/suggest_contacts_reply.cc
    src/contact/suggest_contacts_request.cc
    src/contact/update_contact.cc
    src/contact/update_contact_state.cc
    src/contact/update_contact_state_stream.cc
    src/contact_representative/contact_representative_common_types.cc
    src/contact_representative/contact_representative_info.cc
    src/contact_representative/create_contact_representative.cc
    src/contact_representative/delete_contact_representative.cc
    src/contact_representative/get_history_uuid.cc
    src/contact_representative/get_invalid_fields_of.cc
    src/contact_representative/update_contact_representative.cc
    src/domain/batch_delete_domains.cc
    src/domain/batch_delete_domains_reply.cc
    src/domain/batch_delete_domains_request.cc
    src/domain/check_auction.cc
    src/domain/check_auction_reply.cc
    src/domain/check_auction_request.cc
    src/domain/check_fqdn.cc
    src/domain/check_fqdn_reply.cc
    src/domain/check_fqdn_request.cc
    src/domain/create_domain.cc
    src/domain/create_domain_reply.cc
    src/domain/create_domain_request.cc
    src/domain/delete_domain.cc
    src/domain/delete_domain_reply.cc
    src/domain/delete_domain_request.cc
    src/domain/domain_authinfo.cc
    src/domain/domain_common_types.cc
    src/domain/domain_data_history.cc
    src/domain/domain_history_interval.cc
    src/domain/domain_info.cc
    src/domain/domain_info_reply.cc
    src/domain/domain_info_request.cc
    src/domain/domain_life_cycle_stage_reply.cc
    src/domain/domain_life_cycle_stage_request.cc
    src/domain/domain_service.cc
    src/domain/domain_state.cc
    src/domain/domain_state_flags.cc
    src/domain/domain_state_history.cc
    src/domain/fqdn_history.cc
    src/domain/get_domain_life_cycle_stage.cc
    src/domain/get_domains_by_contact.cc
    src/domain/get_domains_by_contact_reply.cc
    src/domain/get_domains_by_contact_request.cc
    src/domain/get_domains_notify_info.cc
    src/domain/get_domains_notify_info_reply.cc
    src/domain/get_domains_notify_info_request.cc
    src/domain/list_domains.cc
    src/domain/list_domains_request.cc
    src/domain/list_domains_reply.cc
    src/domain/list_domains_by_contact.cc
    src/domain/list_domains_by_contact_request.cc
    src/domain/list_domains_by_contact_reply.cc
    src/domain/list_domains_by_keyset.cc
    src/domain/list_domains_by_keyset_request.cc
    src/domain/list_domains_by_keyset_reply.cc
    src/domain/list_domains_by_nsset.cc
    src/domain/list_domains_by_nsset_request.cc
    src/domain/list_domains_by_nsset_reply.cc
    src/domain/list_domains_by_registrants.cc
    src/domain/list_domains_by_registrants_reply.cc
    src/domain/list_domains_by_registrants_request.cc
    src/domain/manage_domain_state_flags.cc
    src/domain/manage_domain_state_flags_reply.cc
    src/domain/manage_domain_state_flags_request.cc
    src/domain/search_domain.cc
    src/domain/update_domain.cc
    src/domain/update_domain_reply.cc
    src/domain/update_domain_request.cc
    src/domain/update_domains_additional_notify_info.cc
    src/domain/update_domains_additional_notify_info_reply.cc
    src/domain/update_domains_additional_notify_info_request.cc
    src/domain/update_domain_state.cc
    src/domain_blacklist/block_info.cc
    src/domain_blacklist/create_block.cc
    src/domain_blacklist/delete_block.cc
    src/domain_blacklist/domain_blacklist_common_types.cc
    src/domain_blacklist/get_invalid_fields_of.cc
    src/domain_blacklist/list_blocks.cc
    src/keyset/keyset_authinfo.cc
    src/keyset/keyset_common_types.cc
    src/keyset/keyset_data_history.cc
    src/keyset/keyset_handle_history.cc
    src/keyset/keyset_history_interval.cc
    src/keyset/keyset_info.cc
    src/keyset/keyset_info_reply.cc
    src/keyset/keyset_info_request.cc
    src/keyset/keyset_state.cc
    src/keyset/keyset_state_flags.cc
    src/keyset/keyset_state_history.cc
    src/keyset/list_keysets_by_contact.cc
    src/keyset/list_keysets_by_contact_reply.cc
    src/keyset/list_keysets_by_contact_request.cc
    src/keyset/search_keyset.cc
    src/keyset/update_keyset_state.cc
    src/nsset/check_dns_host.cc
    src/nsset/check_dns_host_reply.cc
    src/nsset/check_dns_host_request.cc
    src/nsset/list_nssets.cc
    src/nsset/list_nssets_by_contact.cc
    src/nsset/list_nssets_by_contact_reply.cc
    src/nsset/list_nssets_by_contact_request.cc
    src/nsset/list_nssets_reply.cc
    src/nsset/list_nssets_request.cc
    src/nsset/nsset_authinfo.cc
    src/nsset/nsset_common_types.cc
    src/nsset/nsset_data_history.cc
    src/nsset/nsset_handle_history.cc
    src/nsset/nsset_history_interval.cc
    src/nsset/nsset_info.cc
    src/nsset/nsset_info_reply.cc
    src/nsset/nsset_info_request.cc
    src/nsset/nsset_state.cc
    src/nsset/nsset_state_flags.cc
    src/nsset/nsset_state_history.cc
    src/nsset/search_nsset.cc
    src/nsset/update_nsset_state.cc
    src/object/object_common_types.cc
    src/registrar/add_registrar_certification.cc
    src/registrar/add_registrar_epp_credentials.cc
    src/registrar/add_registrar_group_membership.cc
    src/registrar/add_registrar_zone_access.cc
    src/registrar/create_registrar.cc
    src/registrar/delete_registrar_certification.cc
    src/registrar/delete_registrar_epp_credentials.cc
    src/registrar/delete_registrar_zone_access.cc
    src/registrar/get_registrar_groups_membership.cc
    src/registrar/info_registrar_zone_access.cc
    src/registrar/registrar_certifications.cc
    src/registrar/registrar_common_types.cc
    src/registrar/registrar_credit.cc
    src/registrar/registrar_epp_credentials.cc
    src/registrar/registrar_groups.cc
    src/registrar/registrar_groups_membership.cc
    src/registrar/registrar_info.cc
    src/registrar/registrar_list.cc
    src/registrar/registrar_zone_access.cc
    src/registrar/delete_registrar_group_membership.cc
    src/registrar/update_registrar.cc
    src/registrar/update_registrar_certification.cc
    src/registrar/update_registrar_epp_credentials.cc
    src/registrar/update_registrar_zone_access.cc
    src/util/into.cc
    src/util/sql_exec_in_thread.cc
    src/util/struct_to_string.cc)

add_library(FredRegistryCore::library ALIAS fred-registry-core)

target_link_libraries(fred-registry-core
PUBLIC
    FredRegistryServicesIface::library
    Threads::Threads
PRIVATE
    Boost::program_options
    Fred::library)

add_executable(fred-registry-services
    src/diagnostics/about.cc
    src/diagnostics/status.cc
    src/main.cc)

if(CMAKE_VERSION VERSION_LESS 3.13)
    set(HAS_TARGET_LINK_OPTIONS OFF)
else()
    set(HAS_TARGET_LINK_OPTIONS ON)
endif()

if(HAS_TARGET_LINK_OPTIONS)
    target_link_options(fred-registry-services
        PRIVATE
            "LINKER:--push-state,--no-as-needed" $<TARGET_FILE:gRPC::grpc++_reflection> "LINKER:--pop-state")
else()
    target_link_libraries(fred-registry-services
        PRIVATE
            -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state)
endif()

target_link_libraries(fred-registry-services
PRIVATE
    FredRegistryCore::library
    LibDiagnostics::library
    Fred::library
    gRPC::grpc++)

add_executable(fred-auction-warehouse
    src/auction/warehouse/auction_api.cc
    src/auction/warehouse/cfg.cc
    src/auction/warehouse/fqdn_release.cc
    src/auction/warehouse/process.cc
    src/auction/warehouse/main.cc)

target_link_libraries(fred-auction-warehouse
PRIVATE
    Boost::program_options
    Fred::library
    nlohmann_json::nlohmann_json
    HttpClient::library
    LibLog::library
    PgUtil::library
    Rfc3339::library
    Threads::Threads)

set_common_properties_on_targets(
    fred-auction-warehouse
    fred-registry-services-iface
    fred-registry-services
    fred-registry-core
    http-client
    pg-util
    rfc3339)

# tests

add_executable(test-fred-registry-services
    test/main.cc
    test/setup/fixtures.cc
    test/setup/fixture/cfg.cc
    test/setup/fixture/contact.cc
    test/setup/fixture/registrar.cc
    test/contact/test_contact_data_history.cc
    test/contact/test_contact_handle_history.cc
    test/contact/test_contact_info.cc
    test/contact/test_contact_state.cc
    test/contact/test_contact_state_flags.cc
    test/contact/test_contact_state_history.cc
    test/contact/test_list_contacts_by_state.cc
    test/contact/test_search_contact.cc
    test/contact/test_suggest_contacts.cc
    test/contact/test_update_contact.cc
    test/domain/test_check_auction.cc
    test/domain/test_check_fqdn.cc
    test/domain/test_create_domain.cc
    test/domain/test_delete_domain.cc
    test/domain/test_manage_domain_state_flags.cc
    test/domain/test_search_domain.cc
    test/domain/test_update_domain.cc
    test/keyset/test_search_keyset.cc
    test/nsset/test_search_nsset.cc
    test/util/test_util.cc)

target_link_libraries(test-fred-registry-services PRIVATE
    FredRegistryCore::library
    Fred::library
    Rfc3339::library
    Boost::program_options
    Boost::unit_test_framework
    Threads::Threads)

add_executable(test-client
    test/client.cc)

target_link_libraries(test-client PRIVATE
    FredRegistryCore::library)

set_common_properties_on_targets(
    test-fred-registry-services
    test-client)

# installation

include(GNUInstallDirs)

install(
    TARGETS
        fred-auction-warehouse
        fred-registry-services
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

get_directory_property(HAS_PARENT "PARENT_DIRECTORY")
if(NOT HAS_PARENT)
    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)
endif()

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")

list_package_dependencies_recursive("${PACKAGE_NAME}")
