cmake_minimum_required(VERSION 3.5)

# compile options

set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type. Possible values are empty, Debug, Release, RelWithDebInfo, MinSizeRel, ...")
# CMAKE_<LANG>_FLAGS_<CONFIG> new in cmake version 3.11
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "This will turn on/off logging statements at compile time.")
set(FMT_STRING_ALIAS "1" CACHE STRING "Constructs a compile-time format string.")
set(FMT_HEADER_ONLY "1" CACHE STRING "Use fmt library in the header-only manner.")
option(USE_LIBLOG "Use LibLog for application logging." TRUE)
set(FRED_PUBLIC_REQUEST_DEFAULT_CONFIG_FILE "public_request.conf" CACHE STRING "Specifies the default location of runtime configuration file")
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)

# project details

include("cmake/package.cmake")

package(fred-public-request-services FULL_VERSION "1.2.0")

project(FredPublicRequestServices
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# build options

option(FRED_PUBLIC_REQUEST_SERVICES_BUILD_TESTS "Build ${PACKAGE_NAME} tests" ON)

# externals

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")

# dependencies

find_package(Threads REQUIRED)

set(CMAKE_FIND_PACKAGE_PREFER_CONFIG TRUE)
find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
        system
    REQUIRED)

# configuration files

configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

# build

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PRIVATE
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
        target_compile_definitions(${target_name}
            PRIVATE
                SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
                FMT_STRING_ALIAS=${FMT_STRING_ALIAS}
                FMT_HEADER_ONLY=${FMT_HEADER_ONLY})
    endforeach()
endfunction()

add_library(fred-public-request-services-iface STATIC
    ${FRED_PUBLIC_REQUEST_PROTO_SRCS}
    ${FRED_PUBLIC_REQUEST_GRPC_SRCS})

add_library(FredPublicRequestServicesIface::library ALIAS fred-public-request-services-iface)

foreach(target_name fred-public-request-services-iface)
    message(STATUS "setting grpc properties on: " ${target_name})
    target_compile_options(${target_name}
        PRIVATE
            $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches -Wno-unused-parameter>)
    target_link_libraries(${target_name}
        PUBLIC
            protobuf::libprotobuf
            gRPC::grpc++)
endforeach()

add_library(fred-public-request-core STATIC
    src/lib/get.cc
    src/lib/get_type_traits.cc
    src/lib/invalidate.cc
    src/lib/list.cc
    src/lib/public_request_type_traits.cc
    src/lib/resolve.cc
    src/util/install_pg_log_layer.cc)

add_library(FredPublicRequestCore::library ALIAS fred-public-request-core)

target_include_directories(fred-public-request-core
PUBLIC
    ${CMAKE_CURRENT_SOURCE_DIR})

target_link_libraries(fred-public-request-core
PUBLIC
    Threads::Threads
    Boost::system
    LibLog::library
    LibStrong::library
    LibPg::library
PRIVATE
    Fred::library)

add_library(fred-public-request-grpc STATIC
    src/grpc/public_request_info_service.cc
    src/grpc/public_request_processing_service.cc
    src/grpc/tools/tools.cc
    src/unwrapper/grpc/common_types.cc
    src/unwrapper/grpc/get_request.cc
    src/unwrapper/grpc/invalidate_request.cc
    src/unwrapper/grpc/list_request.cc
    src/unwrapper/grpc/resolve_request.cc
    src/wrapper/grpc/common_types.cc
    src/wrapper/grpc/get_reply.cc
    src/wrapper/grpc/get_types_reply.cc
    src/wrapper/grpc/invalidate_reply.cc
    src/wrapper/grpc/list_reply.cc
    src/wrapper/grpc/public_request_type.cc
    src/wrapper/grpc/resolve_reply.cc)

add_library(FredPublicRequestGrpc::library ALIAS fred-public-request-grpc)

target_link_libraries(fred-public-request-grpc
PUBLIC
    FredPublicRequestServicesIface::library
    FredPublicRequestCore::library
    Threads::Threads
    Boost::system
    LibStrong::library
    LibPg::library
    gRPC::grpc++
PRIVATE
    Fred::library
    LibLog::library)

add_executable(fred-public-request-services
    src/cfg.cc
    src/main.cc
    src/util/util.cc)

if(CMAKE_VERSION VERSION_LESS 3.13)
    set(HAS_TARGET_LINK_OPTIONS OFF)
else()
    set(HAS_TARGET_LINK_OPTIONS ON)
endif()
  
if(HAS_TARGET_LINK_OPTIONS)
    target_link_options(fred-public-request-services
        PRIVATE
            "LINKER:--push-state,--no-as-needed" $<TARGET_FILE:gRPC::grpc++_reflection> "LINKER:--pop-state")
else()
    target_link_libraries(fred-public-request-services
        PRIVATE
            -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state)
endif()

target_link_libraries(fred-public-request-services PRIVATE
    FredPublicRequestGrpc::library
    LibLog::library
    LibDiagnostics::library
    Boost::program_options)

set_common_properties_on_targets(
    fred-public-request-services-iface
    fred-public-request-services
    fred-public-request-core
    fred-public-request-grpc)

# tests

if(FRED_PUBLIC_REQUEST_SERVICES_BUILD_TESTS)
    add_subdirectory(test)
endif()

# installation

include(GNUInstallDirs)

install(TARGETS fred-public-request-services
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

get_directory_property(HAS_PARENT "PARENT_DIRECTORY")
if(NOT HAS_PARENT)
    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)
endif()

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_PREFIX "${FRED-PUBLIC-REQUEST-SERVICES_PREFIX}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")

list_package_dependencies_recursive("${PACKAGE_NAME}")
