cmake_minimum_required(VERSION 3.5)

# compile options

set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type. Possible values are empty, Debug, Release, RelWithDebInfo, MinSizeRel, ...")
# CMAKE_<LANG>_FLAGS_<CONFIG> new in cmake version 3.11
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "This will turn on/off logging statements at compile time.")
option(FMT_STRING_ALIAS "Constructs a compile-time format string." ON)
option(FMT_HEADER_ONLY "Use fmt library in header-only manner." OFF) # OFF value significantly reduce build time
option(USE_LIBLOG "Use LibLog for application logging." TRUE)
set(FRED_IDENTITY_DEFAULT_CONFIG_FILE "identity.conf" CACHE STRING "Specifies the default location of runtime configuration file")
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)

# project details

include("cmake/package.cmake")

package(fred-identity-services FULL_VERSION "2.3.1")

project(FredIdentityServices
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# build options

option(FRED_IDENTITY_SERVICES_BUILD_TESTS "Build ${PACKAGE_NAME} tests" OFF)

# externals

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")

# dependencies

find_package(Threads REQUIRED)

set(CMAKE_FIND_PACKAGE_PREFER_CONFIG TRUE)
find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
        system
    REQUIRED)

# configuration files

configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

# build

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PRIVATE
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
        if(FMT_STRING_ALIAS)
            target_compile_definitions(${target_name} PUBLIC FMT_STRING_ALIAS)
        endif()
        target_compile_definitions(${target_name}
            PRIVATE
                SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
                FMT_HEADER_ONLY=${FMT_HEADER_ONLY})
    endforeach()
endfunction()

add_library(fred-identity-services-iface STATIC
    ${FRED_IDENTITY_PROTO_SRCS}
    ${FRED_IDENTITY_GRPC_SRCS})

add_library(FredIdentityServicesIface::library ALIAS fred-identity-services-iface)

foreach(target_name fred-identity-services-iface)
    message(STATUS "setting grpc properties on: " ${target_name})
    target_compile_options(${target_name}
        PRIVATE
            $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches -Wno-unused-parameter>)
    target_link_libraries(${target_name}
        PUBLIC
            protobuf::libprotobuf
            gRPC::grpc++)
endforeach()

add_library(fred-identity-core STATIC
    src/iface/identity_checker_service.cc
    src/iface/identity_manager_service.cc
    src/iface/identity_user_service.cc
    src/impl/lib/attach_identity.cc
    src/impl/lib/check_current_contact_data.cc
    src/impl/lib/contact_state_flags.cc
    src/impl/lib/create_contact_state_request.cc
    src/impl/lib/detach_identity.cc
    src/impl/lib/get_contact_id_by_handle.cc
    src/impl/lib/get_contacts_by_identity.cc
    src/impl/lib/unwrap_uuid_from_psql.cc
    src/impl/lib/update_identity.cc
    src/impl/lib/wrap_uuid_into_psql.cc
    src/impl/unwrapper/attach_identity_request.cc
    src/impl/unwrapper/check_current_contact_data_request.cc
    src/impl/unwrapper/common_types.cc
    src/impl/unwrapper/detach_identity_request.cc
    src/impl/unwrapper/get_contacts_by_identity_request.cc
    src/impl/unwrapper/get_contact_id_by_handle_request.cc
    src/impl/unwrapper/update_identity_request.cc
    src/impl/wrapper/common_types.cc
    src/impl/wrapper/check_current_contact_data_reply.cc
    src/impl/wrapper/get_contacts_by_identity_reply.cc
    src/util/util.cc
    src/cfg.cc)

add_library(FredIdentityCore::library ALIAS fred-identity-core)

target_link_libraries(fred-identity-core
PUBLIC
    FredIdentityServicesIface::library
    Threads::Threads
    Boost::system
    LibLog::library
    LibStrong::library
    LibPg::library
PRIVATE
    Boost::program_options
    Fred::library)

add_executable(fred-identity-services
    src/iface/tools/tools.cc
    src/main.cc)

if(CMAKE_VERSION VERSION_LESS 3.13)
    set(HAS_TARGET_LINK_OPTIONS OFF)
else()
    set(HAS_TARGET_LINK_OPTIONS ON)
endif()
  
if(HAS_TARGET_LINK_OPTIONS)
    target_link_options(fred-identity-services
        PRIVATE
            "LINKER:--push-state,--no-as-needed" $<TARGET_FILE:gRPC::grpc++_reflection> "LINKER:--pop-state")
else()
    target_link_libraries(fred-identity-services
        PRIVATE
            -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state)
endif()

target_link_libraries(fred-identity-services PRIVATE
    FredIdentityCore::library
    LibLog::library
    LibDiagnostics::library
    gRPC::grpc++)

set_common_properties_on_targets(
    fred-identity-services-iface
    fred-identity-services
    fred-identity-core)

# tests

if(FRED_IDENTITY_SERVICES_BUILD_TESTS)
    add_subdirectory(test)
endif()

# installation

include(GNUInstallDirs)

install(TARGETS fred-identity-services
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

get_directory_property(HAS_PARENT "PARENT_DIRECTORY")
if(NOT HAS_PARENT)
    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)
endif()

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_PREFIX "${FRED-IDENTITY-SERVICES_PREFIX}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")

list_package_dependencies_recursive("${PACKAGE_NAME}")
