cmake_minimum_required(VERSION 3.5)

# compile options

set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Specifies the build type. Possible values are empty, Debug, Release, RelWithDebInfo, MinSizeRel, ...")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
option(THREADS_PREFER_PTHREAD_FLAG "The -pthread compiler and linker flag preference." TRUE)
set(SPDLOG_ACTIVE_LEVEL "SPDLOG_LEVEL_TRACE" CACHE STRING "This will turn on/off logging statements at compile time.")
set(FMT_STRING_ALIAS "1" CACHE STRING "Constructs a compile-time format string.")
set(FMT_HEADER_ONLY "1" CACHE STRING "Use fmt library in the header-only manner.")
option(USE_LIBLOG "Use LibLog for application logging." TRUE)
set(FRED_DNSHOSTING_DEFAULT_CONFIG_FILE "fred-dnshosting-services.conf" CACHE STRING "Specifies the default location of runtime configuration file")
option(CMAKE_EXPORT_COMPILE_COMMANDS "If enabled, generates a compile_commands.json file containing the exact compiler calls." ON)

# project details

include("cmake/package.cmake")

package(fred-dnshosting-services FULL_VERSION "0.5.0")

project(FredDnshostingServices
    VERSION ${PACKAGE_VERSION}
    LANGUAGES CXX)

# build options

option(FRED_DNSHOSTING_SERVICES_BUILD_TESTS "Build ${PACKAGE_NAME} tests" ON)
option(FRED_DNSHOSTING_SERVICES_BUILD_CLIENT "Build ${PACKAGE_NAME} client" ON)

# package dependencies

include("cmake/package_dependencies.cmake")

add_package_dependencies(FROM_FILE "dependencies.txt")

# dependencies

find_package(Threads REQUIRED)
find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
        system
        thread
        unit_test_framework
    REQUIRED)
find_package(PkgConfig REQUIRED)

# configuration files

configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)

# build

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 17
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PRIVATE
                ${CMAKE_CURRENT_SOURCE_DIR}
                ${CMAKE_CURRENT_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
        target_compile_definitions(${target_name}
            PRIVATE
                SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
                FMT_STRING_ALIAS=${FMT_STRING_ALIAS}
                FMT_HEADER_ONLY=${FMT_HEADER_ONLY})
    endforeach()
endfunction()

add_library(fred-dnshosting-services-iface
    ${FRED_DNSHOSTING_PROTO_SRCS}
    ${FRED_DNSHOSTING_GRPC_SRCS})

add_library(FredDnshostingServicesIface::library ALIAS fred-dnshosting-services-iface)

foreach(target_name fred-dnshosting-services-iface)
    message(STATUS "setting grpc properties on: " ${target_name})
    target_compile_options(${target_name}
        PRIVATE
            $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches -Wno-unused-parameter>)
    target_link_libraries(${target_name}
        PUBLIC
            protobuf::libprotobuf
            gRPC::grpc++)
endforeach()

add_library(fred-dnshosting-core STATIC
    src/cfg.cc
    src/cfg/database_options.cc
    src/cfg/dns_hosting_options.cc
    src/cfg/exception.cc
    src/cfg/log_console_options.cc
    src/cfg/log_file_options.cc
    src/cfg/log_options.cc
    src/cfg/log_syslog_options.cc
    src/cfg/util/make_color_mode.cc
    src/cfg/util/make_output_stream.cc
    src/cfg/util/make_severity.cc
    src/grpc/tools/tools.cc
    src/impl/exception.cc
    src/lib/check_unwrapper_attributes.cc
    src/lib/checker.cc
    src/lib/common_types.cc
    src/lib/domain_exists.cc
    src/lib/get_record_domain.cc
    src/lib/get_record_table_name.cc
    src/lib/get_records_by_domain.cc
    src/lib/get_records_history_by_domain.cc
    src/lib/is_record_change_prohibited.cc
    src/lib/manage_records.cc
    src/lib/record_operation/create_a_record.cc
    src/lib/record_operation/create_aaaa_record.cc
    src/lib/record_operation/create_aname_record.cc
    src/lib/record_operation/create_caa_record.cc
    src/lib/record_operation/create_cname_record.cc
    src/lib/record_operation/create_https_record.cc
    src/lib/record_operation/create_mx_record.cc
    src/lib/record_operation/create_srv_record.cc
    src/lib/record_operation/create_sshfp_record.cc
    src/lib/record_operation/create_svcb_record.cc
    src/lib/record_operation/create_tlsa_record.cc
    src/lib/record_operation/create_txt_record.cc
    src/lib/record_operation/delete_a_record.cc
    src/lib/record_operation/delete_aaaa_record.cc
    src/lib/record_operation/delete_aname_record.cc
    src/lib/record_operation/delete_caa_record.cc
    src/lib/record_operation/delete_cname_record.cc
    src/lib/record_operation/delete_https_record.cc
    src/lib/record_operation/delete_mx_record.cc
    src/lib/record_operation/delete_srv_record.cc
    src/lib/record_operation/delete_sshfp_record.cc
    src/lib/record_operation/delete_svcb_record.cc
    src/lib/record_operation/delete_tlsa_record.cc
    src/lib/record_operation/delete_txt_record.cc
    src/lib/record_operation/get_a_records_by_domain.cc
    src/lib/record_operation/get_a_records_history_by_domain.cc
    src/lib/record_operation/get_aaaa_records_by_domain.cc
    src/lib/record_operation/get_aaaa_records_history_by_domain.cc
    src/lib/record_operation/get_aname_records_by_domain.cc
    src/lib/record_operation/get_aname_records_history_by_domain.cc
    src/lib/record_operation/get_caa_records_by_domain.cc
    src/lib/record_operation/get_caa_records_history_by_domain.cc
    src/lib/record_operation/get_cname_records_by_domain.cc
    src/lib/record_operation/get_cname_records_history_by_domain.cc
    src/lib/record_operation/get_https_records_by_domain.cc
    src/lib/record_operation/get_https_records_history_by_domain.cc
    src/lib/record_operation/get_mx_records_by_domain.cc
    src/lib/record_operation/get_mx_records_history_by_domain.cc
    src/lib/record_operation/get_srv_records_by_domain.cc
    src/lib/record_operation/get_srv_records_history_by_domain.cc
    src/lib/record_operation/get_sshfp_records_by_domain.cc
    src/lib/record_operation/get_sshfp_records_history_by_domain.cc
    src/lib/record_operation/get_svcb_records_by_domain.cc
    src/lib/record_operation/get_svcb_records_history_by_domain.cc
    src/lib/record_operation/get_tlsa_records_by_domain.cc
    src/lib/record_operation/get_tlsa_records_history_by_domain.cc
    src/lib/record_operation/get_txt_records_by_domain.cc
    src/lib/record_operation/get_txt_records_history_by_domain.cc
    src/lib/record_operation/update_a_record.cc
    src/lib/record_operation/update_aaaa_record.cc
    src/lib/record_operation/update_aname_record.cc
    src/lib/record_operation/update_caa_record.cc
    src/lib/record_operation/update_cname_record.cc
    src/lib/record_operation/update_https_record.cc
    src/lib/record_operation/update_mx_record.cc
    src/lib/record_operation/update_srv_record.cc
    src/lib/record_operation/update_sshfp_record.cc
    src/lib/record_operation/update_svcb_record.cc
    src/lib/record_operation/update_tlsa_record.cc
    src/lib/record_operation/update_txt_record.cc
    src/unwrapper/grpc/a_record.cc
    src/unwrapper/grpc/aaaa_record.cc
    src/unwrapper/grpc/aname_record.cc
    src/unwrapper/grpc/caa_record.cc
    src/unwrapper/grpc/cname_record.cc
    src/unwrapper/grpc/common_types.cc
    src/unwrapper/grpc/get_records_by_domain_request.cc
    src/unwrapper/grpc/get_records_history_by_domain_request.cc
    src/unwrapper/grpc/https_record.cc
    src/unwrapper/grpc/manage_records_request.cc
    src/unwrapper/grpc/mx_record.cc
    src/unwrapper/grpc/srv_record.cc
    src/unwrapper/grpc/sshfp_record.cc
    src/unwrapper/grpc/svcb_record.cc
    src/unwrapper/grpc/tlsa_record.cc
    src/unwrapper/grpc/txt_record.cc
    src/util/set_logging.cc
    src/util/unwrap_from_psql_representation.cc
    src/util/util.cc
    src/util/uuid.cc
    src/util/wrap_into_psql_representation.cc
    src/wrapper/grpc/a_record.cc
    src/wrapper/grpc/aaaa_record.cc
    src/wrapper/grpc/aname_record.cc
    src/wrapper/grpc/caa_record.cc
    src/wrapper/grpc/cname_record.cc
    src/wrapper/grpc/common_types.cc
    src/wrapper/grpc/error_types.cc
    src/wrapper/grpc/get_records_by_domain_reply.cc
    src/wrapper/grpc/get_records_history_by_domain_reply.cc
    src/wrapper/grpc/google_protobuf_timestamp.cc
    src/wrapper/grpc/https_record.cc
    src/wrapper/grpc/manage_records_reply.cc
    src/wrapper/grpc/mx_record.cc
    src/wrapper/grpc/srv_record.cc
    src/wrapper/grpc/sshfp_record.cc
    src/wrapper/grpc/svcb_record.cc
    src/wrapper/grpc/tlsa_record.cc
    src/wrapper/grpc/txt_record.cc
)

add_library(FredDnshostingServicesCore::library ALIAS fred-dnshosting-core)

target_link_libraries(fred-dnshosting-core
PUBLIC
    FredDnshostingServicesIface::library
    Threads::Threads
    Boost::system
    LibLog::library
    LibStrong::library
    LibPg::library
PRIVATE
    Boost::program_options)

add_executable(fred-dnshosting-services
    src/diagnostics/about.cc
    src/diagnostics/status.cc
    src/grpc/dnsrecord_service.cc
    src/main.cc)

if(CMAKE_VERSION VERSION_LESS 3.13)
    set(HAS_TARGET_LINK_OPTIONS OFF)
else()
    set(HAS_TARGET_LINK_OPTIONS ON)
endif()

if(HAS_TARGET_LINK_OPTIONS)
    target_link_options(fred-dnshosting-services
        PRIVATE
            "LINKER:--push-state,--no-as-needed" $<TARGET_FILE:gRPC::grpc++_reflection> "LINKER:--pop-state")
else()
    target_link_libraries(fred-dnshosting-services
        PRIVATE
            -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state)
endif()

target_link_libraries(fred-dnshosting-services PRIVATE
    FredDnshostingServicesCore::library
    LibLog::library
    LibDiagnostics::library
    gRPC::grpc++)

set_common_properties_on_targets(
    fred-dnshosting-services-iface
    fred-dnshosting-services
    fred-dnshosting-core)

# tests

if(FRED_DNSHOSTING_SERVICES_BUILD_TESTS)
    add_subdirectory(test)
endif()

if(FRED_DNSHOSTING_SERVICES_BUILD_CLIENT)
    add_subdirectory(client)
endif()

# installation

include(GNUInstallDirs)

install(
    TARGETS
        fred-dnshosting-services
    DESTINATION
        ${CMAKE_INSTALL_SBINDIR})

get_directory_property(HAS_PARENT "PARENT_DIRECTORY")
if(NOT HAS_PARENT)
    add_custom_target(uninstall
        COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
        COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)
endif()

# dist

include("cmake/package_dist.cmake")
package_dist(PACKAGE_NAME "${PACKAGE_NAME}"
             PACKAGE_TARNAME "${PACKAGE_TARNAME}")

list_package_dependencies_recursive("${PACKAGE_NAME}")
