cmake_minimum_required(VERSION 3.5)

find_program(GIT_PROGRAM git)
find_program(CCACHE_PROGRAM ccache)

option(DBREPORT_BUILD_TESTS "Build dbreport tests" OFF)

include(GNUInstallDirs)

macro(append_path output_variable_name)
    foreach(ARG ${ARGN})
        if(${output_variable_name})
            string(APPEND ${output_variable_name} "/${ARG}")
        else()
            set(${output_variable_name} "${ARG}")
        endif()
    endforeach()
    string(REGEX REPLACE "//+" "/" ${output_variable_name} "${${output_variable_name}}")
    string(REGEX REPLACE "(.)/$" "\\1" ${output_variable_name} "${${output_variable_name}}")
endmacro()

macro(concat_path output_variable_name)
    set(concat_path_tmp_variable "")
    append_path(concat_path_tmp_variable ${ARGN})
    set(${output_variable_name} "${concat_path_tmp_variable}")
endmacro()

set(SERVER_VERSION "1.1.0")
string(REGEX MATCH "^([0-9]+.[0-9]+.[0-9]+)" SERVER_VERSION_MAJOR_MINOR_PATCH ${SERVER_VERSION})
project(FredDbReportServices
    VERSION ${SERVER_VERSION_MAJOR_MINOR_PATCH}
    LANGUAGES CXX)
message(STATUS "SERVER_VERSION: ${SERVER_VERSION}")

if(CCACHE_PROGRAM)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

set(TARBALL_FILE_NAME "fred-dbreport-services-${SERVER_VERSION}")
set(LIBDIAGNOSTICS_PREFIX ${TARBALL_FILE_NAME}/external/lib/libdiagnostics)
set(LIBLOG_PREFIX ${TARBALL_FILE_NAME}/external/lib/liblog)
set(LIBPG_PREFIX ${TARBALL_FILE_NAME}/external/lib/libpg)

macro(set_default variable_name variable_value)
    if(NOT ${variable_name})
        set(${variable_name} ${variable_value})
    endif()
endmacro()

macro(set_default_path variable_name)
    if(NOT ${variable_name})
        set(${variable_name} "")
        append_path(${variable_name} ${ARGN})
    endif()
endmacro()

set_default(CMAKE_BUILD_TYPE "Release")
set(CMAKE_CXX_FLAGS_RELEASE "-O2 -DNDEBUG")
set_default(THREADS_PREFER_PTHREAD_FLAG ON)
set_default(SPDLOG_ACTIVE_LEVEL 0)
set_default(FMT_STRING_ALIAS 1)
set_default(FMT_HEADER_ONLY 1)
set_default(CMAKE_EXPORT_COMPILE_COMMANDS ON)

find_package(Threads REQUIRED)

find_package(Boost 1.53.0
    COMPONENTS
        date_time
        program_options
    REQUIRED)

function(set_common_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting common properties on: " ${target_name})
        set_target_properties(${target_name} PROPERTIES
            CXX_STANDARD 14
            CXX_STANDARD_REQUIRED YES
            CXX_EXTENSIONS NO
            ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/lib"
            RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/bin")
        target_include_directories(${target_name}
            PUBLIC
                ${CMAKE_SOURCE_DIR}
                ${CMAKE_BINARY_DIR})
        target_compile_options(${target_name}
            PRIVATE
                $<$<CXX_COMPILER_ID:GNU>:-Wall -Wextra -ggdb -grecord-gcc-switches>)
        target_compile_definitions(${target_name}
            PRIVATE
                SPDLOG_ACTIVE_LEVEL=${SPDLOG_ACTIVE_LEVEL}
                FMT_STRING_ALIAS=${FMT_STRING_ALIAS}
                FMT_HEADER_ONLY=${FMT_HEADER_ONLY})
    endforeach()
endfunction()

set_default(LIBDIAGNOSTICS_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/libdiagnostics)
if(NOT IS_ABSOLUTE ${LIBDIAGNOSTICS_DIR})
    set(LIBDIAGNOSTICS_DIR ${CMAKE_BINARY_DIR}/${LIBDIAGNOSTICS_DIR})
endif()
if(NOT EXISTS ${LIBDIAGNOSTICS_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBDIAGNOSTICS_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBDIAGNOSTICS_DIR")
endif()

set_default_path(LIBLOG_DIR "${CMAKE_CURRENT_SOURCE_DIR}" external/lib/liblog)
if(NOT IS_ABSOLUTE ${LIBLOG_DIR})
    concat_path(LIBLOG_DIR "${CMAKE_BINARY_DIR}" "${LIBLOG_DIR}")
endif()
if(NOT EXISTS ${LIBLOG_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBLOG_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBLOG_DIR")
endif()

if(NOT LIBSTRONG_DIR)
    set(LIBSTRONG_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/lib/libstrong)
    if(NOT EXISTS ${LIBSTRONG_DIR}/CMakeLists.txt)
        message(FATAL_ERROR "no ${LIBSTRONG_DIR}/CMakeLists.txt file found; use -DLIBSTRONG_DIR=<path> "
                            "to specify a LibStrong location")
    endif()
else()
    if(NOT IS_ABSOLUTE ${LIBSTRONG_DIR})
        set(LIBSTRONG_DIR ${CMAKE_CURRENT_SOURCE_DIR}/${LIBSTRONG_DIR})
    endif()
    if(NOT EXISTS ${LIBSTRONG_DIR}/CMakeLists.txt)
        message(FATAL_ERROR "no ${LIBSTRONG_DIR}/CMakeLists.txt file found; LIBSTRONG_DIR "
                            "does not refer a LibStrong location")
    endif()
endif()

set_default_path(LIBPG_DIR "${CMAKE_CURRENT_SOURCE_DIR}" external/lib/libpg)
if(NOT IS_ABSOLUTE ${LIBPG_DIR})
    concat_path(LIBPG_DIR "${CMAKE_BINARY_DIR}" "${LIBPG_DIR}")
endif()
if(NOT EXISTS ${LIBPG_DIR}/CMakeLists.txt)
    message(FATAL_ERROR "${LIBPG_DIR}/CMakeLists.txt does not exist; you need to pass -DLIBPG_DIR")
endif()

if(NOT TARGET LibDiagnostics::library)
    add_subdirectory(${LIBDIAGNOSTICS_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/libdiagnostics EXCLUDE_FROM_ALL)
endif()
if(NOT TARGET LibLog::library)
    add_subdirectory(${LIBLOG_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/liblog EXCLUDE_FROM_ALL)
endif()
if(NOT TARGET LibStrong::library)
    add_subdirectory(${LIBSTRONG_DIR} ${CMAKE_BINARY_DIR}/external/lib/libstrong EXCLUDE_FROM_ALL)
endif()
if(NOT TARGET LibPg::library)
    add_subdirectory(${LIBPG_DIR} ${CMAKE_CURRENT_BINARY_DIR}/external/lib/libpg EXCLUDE_FROM_ALL)
endif()

set_default_path(API_DBREPORT_DIR "${CMAKE_CURRENT_SOURCE_DIR}" external/api/dbreport)
if(NOT IS_ABSOLUTE ${API_DBREPORT_DIR})
    concat_path(API_DBREPORT_DIR "${CMAKE_BINARY_DIR}" "${API_DBREPORT_DIR}")
endif()
if(NOT EXISTS ${API_DBREPORT_DIR}/cmake/c++.cmake)
    message(FATAL_ERROR "${API_DBREPORT_DIR}/cmake/c++.cmake does not exist; you need to pass -DAPI_DBREPORT_DIR")
endif()
include("${API_DBREPORT_DIR}/cmake/c++.cmake")

set_default(PACKAGE fred-dbreport-services)
set_default(HAVE_BOOST_SERIALIZATION 1)
set_default_path(DEFAULT_CONFIG_FILE "${CMAKE_INSTALL_FULL_SYSCONFDIR}" fred/fred-dbreport.conf)

configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)

if(CMAKE_VERSION VERSION_LESS 3.13)
  set(HAS_TARGET_LINK_OPTIONS OFF)
else()
  set(HAS_TARGET_LINK_OPTIONS ON)
endif()

function(set_grpc_properties_on_targets)
    foreach(target_name ${ARGN})
        message(STATUS "setting grpc properties on: " ${target_name})
        target_compile_options(${target_name}
            PRIVATE
                "-Wno-unused-parameter")
        target_link_libraries(${target_name}
            PUBLIC
                protobuf::libprotobuf)
    endforeach()
endfunction()

add_library(dbreport-lib STATIC
    src/impl/lib/list_reports.cc
    src/impl/lib/manage_reports.cc
    src/impl/lib/run_report.cc)

add_library(DbReportLib::library ALIAS dbreport-lib)

target_link_libraries(dbreport-lib
    LibLog::library
    LibPg::library
    LibStrong::library)

add_library(dbreport-cfg STATIC
    src/cfg.cc)

add_library(DbReportCfg::library ALIAS dbreport-cfg)

target_link_libraries(dbreport-cfg
    Boost::program_options
    LibLog::library)

add_library(dbreport-core STATIC
    src/iface/report_manager_service.cc
    src/iface/report_user_service.cc
    src/iface/tools/common_types_wrappers.cc
    src/iface/tools/run_report_unwrappers.cc
    src/iface/tools/tools.cc
    src/impl/common_types.cc
    src/impl/list_reports.cc
    src/impl/manage_reports.cc
    src/impl/run_report.cc
    src/util/util.cc)

add_library(DbReportCore::library ALIAS dbreport-core)

add_library(fred-dbreport-services-iface STATIC
    ${FRED_DBREPORT_PROTO_SRCS}
    ${FRED_DBREPORT_GRPC_SRCS})

add_library(FredDbReportServicesIface::library ALIAS fred-dbreport-services-iface)

set_grpc_properties_on_targets(fred-dbreport-services-iface)

target_link_libraries(dbreport-core
    FredDbReportServicesIface::library
    DbReportCfg::library
    Threads::Threads
    DbReportLib::library
    LibLog::library
    LibPg::library
    LibStrong::library)

add_executable(fred-dbreport-services
    src/main.cc)
if(HAS_TARGET_LINK_OPTIONS)
    target_link_options(fred-dbreport-services
        INTERFACE
            "LINKER:--push-state,--no-as-needed" gRPC::grpc++_reflection "LINKER:--pop-state")
else()
    target_link_libraries(fred-dbreport-services
        INTERFACE
            -Wl,--push-state,--no-as-needed gRPC::grpc++_reflection -Wl,--pop-state)
endif()

target_link_libraries(fred-dbreport-services PRIVATE
    FredDiagnosticsServicesIface::library
    LibDiagnostics::library
    DbReportCore::library)

set_common_properties_on_targets(
    fred-dbreport-services-iface
    fred-dbreport-services
    dbreport-cfg
    dbreport-core
    dbreport-lib)

if(DBREPORT_BUILD_TESTS)
    add_subdirectory(test)
endif()

install(TARGETS ${PACKAGE}
    DESTINATION ${CMAKE_INSTALL_SBINDIR})

add_custom_target(uninstall
    COMMAND xargs -L10 rm -v < ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt
    COMMAND cat ${CMAKE_CURRENT_BINARY_DIR}/install_manifest.txt | xargs -L1 dirname | sort | uniq | xargs -L10 rmdir -p --ignore-fail-on-non-empty)

if(EXISTS ${CMAKE_SOURCE_DIR}/.git AND GIT_PROGRAM)
    if(NOT TARGET dist)
        add_custom_target(dist_api_dbreport
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/api/dbreport/ HEAD > ${CMAKE_BINARY_DIR}/.api-dbreport.tar
            WORKING_DIRECTORY ${API_DBREPORT_DIR})
        if (NOT TARGET dist_libdiagnostics)
            add_custom_target(dist_libdiagnostics_api_diagnostics
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/libdiagnostics/external/api/diagnostics/ HEAD > ${CMAKE_BINARY_DIR}/.libdiagnostics.api-diagnostics.tar
                WORKING_DIRECTORY ${LIBDIAGNOSTICS_DIR}/external/api/diagnostics/)
            add_custom_target(dist_libdiagnostics
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/libdiagnostics/ HEAD > ${CMAKE_BINARY_DIR}/.libdiagnostics.tar
                COMMAND [ ! -f ${CMAKE_BINARY_DIR}/.libdiagnostics.api-diagnostics.tar ] || (tar --concatenate --file=${CMAKE_BINARY_DIR}/.libdiagnostics.tar ${CMAKE_BINARY_DIR}/.libdiagnostics.api-diagnostics.tar && rm ${CMAKE_BINARY_DIR}/.libdiagnostics.api-diagnostics.tar)
                DEPENDS dist_libdiagnostics_api_diagnostics
                WORKING_DIRECTORY ${LIBDIAGNOSTICS_DIR})
        endif()
        if (NOT TARGET dist_liblog)
            add_custom_target(dist_liblog_spdlog
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblog/3rd_party/lib/spdlog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar
                WORKING_DIRECTORY ${LIBLOG_DIR}/3rd_party/lib/spdlog/)
            add_custom_target(dist_liblog
                COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/external/lib/liblog/ HEAD > ${CMAKE_BINARY_DIR}/.liblog.tar
                COMMAND [ ! -f ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar ] || (tar --concatenate --file=${CMAKE_BINARY_DIR}/.liblog.tar ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar && rm ${CMAKE_BINARY_DIR}/.liblog_spdlog.tar)
                DEPENDS dist_liblog_spdlog
                WORKING_DIRECTORY ${LIBLOG_DIR})
        endif()
        add_custom_target(dist
            COMMAND ${GIT_PROGRAM} archive --format=tar --prefix=${TARBALL_FILE_NAME}/ HEAD > ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
            COMMAND [ ! -f ${CMAKE_BINARY_DIR}/.api-dbreport.tar ] || (tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.api-dbreport.tar && rm ${CMAKE_BINARY_DIR}/.api-dbreport.tar)
            COMMAND [ ! -f ${CMAKE_BINARY_DIR}/.libdiagnostics.tar ] || (tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.libdiagnostics.tar && rm ${CMAKE_BINARY_DIR}/.libdiagnostics.tar)
            COMMAND [ ! -f ${CMAKE_BINARY_DIR}/.liblog.tar ] || (tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.liblog.tar && rm ${CMAKE_BINARY_DIR}/.liblog.tar)
            COMMAND [ ! -f ${CMAKE_BINARY_DIR}/.libpg.tar ] || (tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.libpg.tar && rm ${CMAKE_BINARY_DIR}/.libpg.tar)
            COMMAND [ ! -f ${CMAKE_BINARY_DIR}/.libstrong.tar ] || (tar --concatenate --file=${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar ${CMAKE_BINARY_DIR}/.libstrong.tar && rm ${CMAKE_BINARY_DIR}/.libstrong.tar)
            COMMAND cat ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar | gzip > ${CMAKE_BINARY_DIR}/${TARBALL_FILE_NAME}.tar.gz && rm ${CMAKE_BINARY_DIR}/.${TARBALL_FILE_NAME}.tar
            DEPENDS dist_api_dbreport
                    dist_libdiagnostics
                    dist_liblog
                    dist_libpg
                    dist_libstrong
            WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
    endif()

    if(DEFINED ENV{DISTCHECK_CMAKE_FLAGS})
        set(distcheck_flags $ENV{DISTCHECK_CMAKE_FLAGS})
    endif()

    if(NOT TARGET distcheck)
        set(DISTCHECK_BUILD_DIR "_build")
        set(DISTCHECK_INSTALL_DIR "_inst")
        if(${CMAKE_GENERATOR} STREQUAL "Ninja")
            set(DISTCHECK_BUILD_CMD "ninja")
        else()
            set(DISTCHECK_BUILD_CMD "$(MAKE)")
        endif()
        add_custom_target(clean_before_distcheck
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            COMMENT "cleaning before distcheck start")
        add_custom_target(distcheck_make_dirs
            COMMAND mkdir ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR}
            COMMENT "make distcheck build and install directories"
            DEPENDS clean_before_distcheck)
        add_custom_target(distcheck_unpack_archive
            COMMAND tar xzf ${TARBALL_FILE_NAME}.tar.gz
            COMMENT "Checking the distribution archive..."
            DEPENDS dist distcheck_make_dirs)
        add_custom_target(distcheck_configure
            COMMAND ${CMAKE_COMMAND} -G${CMAKE_GENERATOR} ${distcheck_flags} -DSERVER_VERSION=${SERVER_VERSION} -DCMAKE_INSTALL_PREFIX=../${DISTCHECK_INSTALL_DIR} ../${TARBALL_FILE_NAME}
            COMMENT "configure distcheck"
            DEPENDS distcheck_unpack_archive
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_make
            COMMAND ${DISTCHECK_BUILD_CMD}
            COMMENT "make"
            DEPENDS distcheck_configure
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_install
            COMMAND ${DISTCHECK_BUILD_CMD} install
            COMMENT "make install"
            DEPENDS distcheck_make
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_uninstall
            COMMAND ${DISTCHECK_BUILD_CMD} uninstall
            COMMENT "make uninstall"
            DEPENDS distcheck_install
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck_clean
            COMMAND ${DISTCHECK_BUILD_CMD} clean
            COMMENT "make clean"
            DEPENDS distcheck_uninstall
            WORKING_DIRECTORY ${DISTCHECK_BUILD_DIR})
        add_custom_target(distcheck
            COMMAND rm -rf ${DISTCHECK_BUILD_DIR} ${DISTCHECK_INSTALL_DIR} ${TARBALL_FILE_NAME}
            COMMENT "PASS: '${TARBALL_FILE_NAME}.tar.gz' is ready for distribution."
            DEPENDS distcheck_clean)
    endif()
else()
    message(STATUS "no git -- not including dist and distcheck targets")
endif()
